home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / genie-commodore-file-library / C64-128Toolkit / MSD-DU17.ARC / DEVICE# CBM / MSD (.txt)
Encoding:
Commodore BASIC  |  2019-04-13  |  1.3 KB  |  46 lines
  1. 45 REM*******************************
  2. 50 REM* MSD & COMMODORE DISK DEVICE *
  3. 55 REM* NUMBER CHANGER MODIFICATION *
  4. 60 REM*     BY DAVID W. MARTIN      *
  5. 65 REM*******************************
  6. 100 POKE59468,12
  7. 110 PRINT"[147]DRIVE ADDRESS CHANGE PROGRAM"
  8. 111 PRINT"TURN OFF ALL DRIVES NOW"
  9. 112 PRINT"EXCEPT THE ONE TO BE CHANGED."
  10. 120 PRINT"OLD DEVICE ADDRESS  8[157][157][157]";
  11. 130 INPUT OD: IF OD<8 OR OD>15 GOTO 120
  12. 140 PRINT"NEW DEVICE ADDRESS  9[157][157][157]";
  13. 150 INPUT ND: IF ND<8 OR ND>15 GOTO 140
  14. 160 GOSUB 300: REM FIND DRIVE TYPE
  15. 170 GOSUB 600: REM CHANGE ADDRESS
  16. 180 PRINT"THE SELECTED DRIVE HAS BEEN CHANGED..."
  17. 185 PRINT"NOW TURN ON THE OTHER DRIVE(S)"
  18. 190 END
  19. 300 REM: IDENTIFY DRIVE TYPE
  20. 310 CLOSE15:OPEN15,OD,15
  21. 320 PRINT#15,"M-R"CHR$(255)CHR$(255):GET#15,C$:C=ASC(C$+CHR$(0))
  22. 330 IF ST THEN 1000
  23. 340 IF C=254 THEN MT=119: REM: 2031 V2.6
  24. 345 IF C=254 THEN GOSUB 391:REM MSD?
  25. 350 IF C=226 THEN MT=50: REM: 2040 V1.2
  26. 360 IF C=213 THEN MT=12: REM: 4040 V2.1
  27. 370 IF C=242 THEN MT=12: REM: 8050 V2.5
  28. 380 IF C=198 THEN 400
  29. 390 RETURN
  30. 391 PRINT#15,"M-R"CHR$(0)CHR$(192)CHR$(3):GET#15,CD$
  31. 392 IFCD$="2.3"THENMT=119:REM MSD 2.3
  32. 393 RETURN
  33. 400 PRINT#15,"M-R"CHR$(234)CHR$(16):GET#15,ZB$:ZB=ASC(ZB$+CHR$(0))
  34. 410 IF ZB=0 THEN MT=12: REM: 4040 V2.7
  35. 420 IF ZB=1 THEN 440
  36. 430 IF ST THEN 1000
  37. 440 PRINT#15,"M-R"CHR$(172)CHR$(16):GET#15,ZC$:ZC=ASC(ZC$+CHR$(0))
  38. 450 IF ZC=1 THEN MT=12: REM: 8050 V2.7
  39. 460 IF ZC=2 THEN MT=12: REM: 8250 V2.7
  40. 470 RETURN
  41. 600 CLOSE15: OPEN15,OD,15
  42. 610 PRINT#15,"M-W"CHR$(MT)CHR$(0)CHR$(2)CHR$(ND+32)CHR$(ND+64)
  43. 630 RETURN
  44. 1000 PRINT" DEVICE  ERROR "
  45. 1010 END
  46.